
# 通过【后台鼠标】实现在【画图】窗口上绘制图形

#MKScript窗口文本框初始化显示的内容
mkscript_window_initial_text("通过【后台鼠标】实现在【画图】窗口上绘制图形\r\n\r\n")


#是否启动画图: mspaint.exe
int run_mspaint = 0

#自定义标签
start:

#查找【画图】窗口
int hwnd = window_find("", "无标题 - 画图")
#println("hwnd:" + hwnd)

if hwnd == 0

    if run_mspaint == 0

        #启动【画图】
        run("mspaint.exe")
        
        #暂停 2 秒: 等待【画图】窗口显示
        sleep(2000)

        #标注:启动了一次【画图】
        run_mspaint = 1
        
        #重试
        goto start
        
    else

        alert("没有找到【画图】窗口")
        exit(0)
    
    endif
    
else

    #如果窗口最小化, 就恢复显示
    if window_is_iconic(hwnd) == mkTrue
        window_show(hwnd, mkSW_RESTORE)
    endif
    
    #查找【画图】中类名: MSPaintView 的窗口
    hwnd = window_find_ex(hwnd, 0, "MSPaintView", "")
    
    if hwnd == 0
    
        alert("没有找到【画图】窗口中类名为 MSPaintView 的窗口")
        exit(0)
        
    else
    
        #查找【画图】中类名: Afx:2c0000:8 的窗口
        hwnd = window_find_ex(hwnd, 0, "", "")
        
        if hwnd == 0
    
            alert("没有找到【画图】窗口中类名为 MSPaintView 的子窗口")
            exit(0)
        
        endif
    
    endif
    
    #清除当前显示的内容
    cls()
    
    #在 MKScript 窗口输出文字
    println("开始在【画图】窗口中绘制图形...")
    
    #按下鼠标左键
    window_mouse_left_down(hwnd, 10, 10)
    window_mouse_left_up(hwnd, 100, 10)
    
    #暂停1秒
    sleep(1000)
    
    window_mouse_left_down(hwnd, 10, 10)
    window_mouse_left_up(hwnd, 10, 100)
    
    #暂停1秒
    sleep(1000)
    
    window_mouse_left_down(hwnd, 100, 10)
    window_mouse_left_up(hwnd, 10, 100)
    
    
    #清除当前显示的内容
    cls()
    
    #在 MKScript 窗口输出文字
    println("【画图】窗口绘制图形完成。")
    
    #重置
    run_mspaint = 0
    
    #暂停
    pause(mkFalse)
    
    #再来一次    
    goto start    

endif
