#实现在记事本上和MKScript的【信息框】同步输出文件: 关于梦想.txt 的内容
#使用 key_xxx 的时候，要注意当前键盘的输入法状态

#预处理函数: 可配置 MKScript 脚本加载后自动运行
#mkscript_config_auto_start()

#预处理函数: 初始化MKScript窗口大小和位置
mkscript_window_initial_size(800, 300)
mkscript_window_initial_position(800, 500)

#打开一个【记事本】
run("notepad")

#暂停一下: 打开【记事本】需要一点时间
sleep(500)

#查找【记事本】窗口
int hWindow = window_find("", "无标题 - 记事本")
 
if hWindow > 0
 
    #找到【记事本】窗口
  
    #如果窗口当前最小化了
    if window_is_iconic(hWindow) == mkTrue
    
        #恢复窗口显示
        window_show(hWindow, mkSW_RESTORE)
    
    endif
 
    #激活窗口
    window_set_active(hWindow)
    
    #暂停 0.5 秒
    sleep(500)
    
else
 
    #没找到【记事本】窗口
 
    #弹出信息提示对话框
    alert("在点【确定】按钮前，先新建一个空白的【文本文档】并打开。\r\n\r\n在点【确定】按钮后的 3 秒内，将焦点移到空白的【记事本】中。")
    
    #暂停 3 秒
    sleep(3000)
 
endif

#存储txt文件内容
string body

int status = file_read("关于梦想.txt", body)

if status == mkTrue

    int bodyLen = len(body)

    for int i = 0 to bodyLen - 1

        char c = char_at(body, i)        

        if(c != '\r')
            key_char(c)
        endif
        
        print(c)

    next
    
else

    alert("没有找到 关于梦想.txt 文件")
    exit()

endif
